Vraisemblablement, vous avez un nombre inconnu de résultats, éventuellement jusqu'à 8 résultats. Il est donc préférable d'utiliser quelque chose pour stocker les résultats, dont le stockage peut être étendu selon les besoins pour accueillir autant de résultats renvoyés par la requête : vous pouvez utiliser une Liste pour cela, à condition de créer quelque chose qui puisse contenir tout. renvoyé pour chaque ligne d'une requête de liste - il peut s'agir d'une classe avec des propriétés contenant chaque variable. Il est probablement plus facile de regarder le code que j'ai suggéré que de l'expliquer :

Public Class ToolDatum
    Public Property ToolID As String
    Public Property LopendeMeter As Double

    Public Sub New()
        ' Empty constructor
    End Sub

    Public Sub New(werktuignummer As String, LopendeMeter As Double)
        Me.ToolID = werktuignummer
        Me.LopendeMeter = LopendeMeter
    End Sub

End Class

Public Function GetData() As List(Of ToolDatum)
    Dim toolData As New List(Of ToolDatum)

    Dim connStr As String = My.Settings.sCnnStr
    Dim sql As String = "SELECT pfProfielfreesnummer, pfLopendemeters
                         FROM actuelewerktuigselectie
                         WHERE (awsId = @P1 OR awsId = @P2 OR awsId = @P3 OR awsId = @P4 OR awsId = @P5 OR awsId = @P6 OR awsId = @P7 OR awsId = @P8)"

    Using conn = New MySqlConnection(connStr),
           cmd = New MySqlCommand(sql, conn)

        cmd.Parameters.Add("@P1", MySqlDbType.Int32).Value = 5
        cmd.Parameters.Add("@P2", MySqlDbType.Int32).Value = 6
        cmd.Parameters.Add("@P3", MySqlDbType.Int32).Value = 7
        cmd.Parameters.Add("@P4", MySqlDbType.Int32).Value = 8
        cmd.Parameters.Add("@P5", MySqlDbType.Int32).Value = 17
        cmd.Parameters.Add("@P6", MySqlDbType.Int32).Value = 18
        cmd.Parameters.Add("@P7", MySqlDbType.Int32).Value = 19
        cmd.Parameters.Add("@P8", MySqlDbType.Int32).Value = 20

        conn.Open()

        Using myReader = cmd.ExecuteReader()
            While (myReader.Read())
                toolData.Add(New ToolDatum(myReader.GetString(0), myReader.GetDouble(1)))
            End While

        End Using

    End Using

    Return toolData

End Function

La fonction GetData (vous devez lui donner un nom descriptif) renverra une liste que vous pourrez parcourir pour obtenir chaque résultat individuel, comme

Dim q = GetData()
For Each r In q
    Console.WriteLine(r.ToolID & " " & r.LopendeMeter)
Next

Je le ferai AddWithValue 更改为 Add car le premier peut causer des problèmes inattendus. J'ai modifié les noms des paramètres pour qu'ils commencent par une lettre afin d'éviter d'autres problèmes inattendus.

Utilisez des déclarations a> pour garantir que les éléments qui doivent gérer des ressources non gérées sont pris en charge.